Industriële fabricage
Industrieel internet der dingen | Industriële materialen | Onderhoud en reparatie van apparatuur | Industriële programmering |
home  MfgRobots >> Industriële fabricage >  >> Manufacturing Technology >> Productieproces

Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie

Onderdelen en benodigdheden

Onderdeel Aantal
Arduino Nano R3 1
Lasermodule KY-008 1
LM393 Lichtsensormodule 1
Algemene NPN-transistor 3
Draaipotentiometer 1
C&K PTS 645 Series drukknop 1

Apps en online diensten

  • Arduino IDE

Over dit project

Dit project ontstond uit de wens high-speed fotografie van waterdruppels te proberen. Hier is een eenvoudige Arduino-opstelling om het moment van botsing vast te leggen.

Benodigdheden

  • Camera met handmatige instellingen en externe flitser, beide met afstandsbediening (bijv. Sony DSC-HX300 en Godox SY8000).
  • De afstandsbediening wordt gemodificeerd met een 3-pins header om via Arduino de shutter te bedienen.
  • De Sync-kabel van de flitser werkt op dezelfde manier: kortsluiten van de PC-connector contacten vuurt de flitser.
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie

Druppeldetectie

Een medicijndruppelaar wordt gebruikt als druppelvormer. De lasermodule KY-008 en LM393 lichtsensor detecteren de vallende druppel: de druppel onderbreekt de laserstraal, wat de sensor detecteert. De gevoeligheid is instelbaar via de potentiometer op de sensormodule.

Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie

Werking

De opname gebeurt in het donker met lange belichting (seconden), zodat alleen de flitser het beeld bepaalt. De gebruiker drukt op de knop vóór de zichtbare druppelval. Dit opent de shutter (via autofocus en shutter triggers) en activeert de flitser-trigger. Wanneer de druppel de laser onderbreekt, wordt de flitser gevuurd na een vertraging (1-500 ms, instelbaar met potentiometer). Volgende druppels vuren niet tenzij de knop opnieuw wordt ingedrukt.

Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie

Optioneel: een optokoppler toevoegen om de hoge-spanningsflitser te isoleren van de lage-spanningselektronica.

Code parameters

Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
  • DBG_MODE: voor testen zonder camera/flitser (gebruikt ingebouwde LED).
  • Pinnen voor knop, focus, shutter, flitser, sensor, potentiometer.
  • Vertragingen voor focus, shutter, flitser.
  • Limieten voor vuurvertraging (1-500 ms).

Resultaten

Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie
Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie

Code

Arduino Sketch

//#define DBG_MODE
const byte BUTTON_PIN = 2;
const byte FOCUS_PIN = 3;
const byte SHUTTER_PIN = 4;
const byte FLASH_PIN = 5;
const byte SENSOR_PIN = 6;
const byte RESISTOR_PIN = A5;
const unsigned int FOCUS_DELAY = 100;
const unsigned int SHUTTER_DELAY = 100;
const unsigned int FLASH_DELAY = 10;
const unsigned int FIRE_DELAY_MIN = 1;
const unsigned int FIRE_DELAY_MAX = 500;

boolean prevButton, currButton;
boolean prevSensor, currSensor;
boolean allowFlash;
unsigned long fireDelay;

void openShutter() {
  #ifndef DBG_MODE
  digitalWrite(FOCUS_PIN, HIGH); delay(FOCUS_DELAY);
  digitalWrite(SHUTTER_PIN, HIGH); delay(SHUTTER_DELAY);
  digitalWrite(SHUTTER_PIN, LOW); delay(FOCUS_DELAY);
  digitalWrite(FOCUS_PIN, LOW);
  #else
  digitalWrite(LED_BUILTIN, HIGH);
  #endif
}

void fireFlash() {
  #ifndef DBG_MODE
  digitalWrite(FLASH_PIN, HIGH); delay(FLASH_DELAY);
  digitalWrite(FLASH_PIN, LOW);
  #else
  digitalWrite(LED_BUILTIN, LOW);
  #endif
}

void setup() {
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  pinMode(FOCUS_PIN, OUTPUT);
  pinMode(SHUTTER_PIN, OUTPUT);
  pinMode(FLASH_PIN, OUTPUT);
  pinMode(SENSOR_PIN, INPUT);
  #ifdef DBG_MODE
  pinMode(LED_BUILTIN, OUTPUT);
  #endif
  digitalWrite(FOCUS_PIN, LOW);
  digitalWrite(SHUTTER_PIN, LOW);
  digitalWrite(FLASH_PIN, LOW);
  prevButton = digitalRead(BUTTON_PIN);
  prevSensor = digitalRead(SENSOR_PIN);
  allowFlash = false;
}

void loop() {
  currButton = digitalRead(BUTTON_PIN);
  if (prevButton != currButton) {
    prevButton = currButton;
    if (currButton == LOW) {
      allowFlash = true;
      prevSensor = HIGH;
      fireDelay = map(analogRead(RESISTOR_PIN), 0, 1023, FIRE_DELAY_MIN, FIRE_DELAY_MAX);
      openShutter();
    } else { delay(50); }
  }
  currSensor = digitalRead(SENSOR_PIN);
  if (prevSensor != currSensor) {
    prevSensor = currSensor;
    if (currSensor == HIGH && allowFlash) {
      allowFlash = false;
      delay(fireDelay);
      fireFlash();
    }
  }
}

Schema's

Waterdruppels vastleggen met Arduino Nano – DIY High-Speed Fotografie

Productieproces

  1. Slimme spaarpot bouwen: Muntenacceptor besturen met Arduino Nano
  2. IoT & AI-gestuurde Waterkwaliteitsmonitoring Beschermt Aquatisch Leven
  3. JX Wave Generator – Arduino-compatibele DDS-oscillator met OLED-display
  4. Een LED bedienen via Bluetooth met Arduino – Eenvoudige DIY Handleiding
  5. Monitor Je Huistemperatuur Overal met Arduino Cloud Integratie
  6. Arduino Mega koppelen aan een NEO‑6M GPS-module: stapsgewijze handleiding
  7. u-blox LEA‑6H GPS Module: Arduino & Python Integratie Handleiding
  8. MAX30100 hartslagsensor integreren met Arduino: Stapsgewijze handleiding
  9. De Fridgeye-app bouwen met een Nextion-display: stapsgewijze handleiding
  10. Stapsgewijze handleiding: YL-39/YL-69 bodemvochtigheidsensor aan Arduino UNO koppelen
  11. Accurate zonnestralingsmeting met Arduino UNO en Ethernet Shield