Morsecode Zender Bouwen met Arduino – Eenvoudige DIY Handleiding
Onderdelen en benodigdheden
| Arduino UNO | 1 | |
| SparkFun Drukknop 12mm | 2 | Ik heb twee-pins drukknoppen gebruikt |
| LED (standaard) | 1 | |
| Buzzer | 1 | |
| Weerstand 330 ohm | 4 | |
| Breadboard (standaard) | 1 | |
| Jumper wires (standaard) | 10 | Enkele draden voor verbinding van Arduino bord naar breadboard |
Apps en online diensten
- Arduino IDE
Over dit project
Idee Beschrijving
We communiceren allemaal met elkaar via onze natuurlijke zintuigen (taal, gebaren... etc). Het spannende deel begint wanneer u geheime informatie wilt delen met iemand. De vraag is: hoe doet u dat?
Het antwoord ligt in hoe u informatie overdraagt op een manier dat zelfs als een derde persoon het bericht ziet, hij het niet kan begrijpen tenzij hij de sleutel vindt. Voor dit doel gebruikte ik Morsecode-communicatie; u kunt ook een andere manier gebruiken om deze taak te volbrengen.
Wat is Morsecode?
Morsecode is een communicatiemethode om informatie door te geven door de oorspronkelijke letters te representeren als combinaties van punten . en strepen - . Bijvoorbeeld: A → .- en B → -...
Voor meer informatie over Morsecode, klik op de onderstaande link:
https://wrvmuseum.org/morsecodehistory.htm

Waarom ik Morsecode koos?
De reden is simpel: onlangs keek ik een film waarin een agent informatie doorgeef door op een knop te klikken, en aan de ontvangende kant decodeerden anderen het. Dus ik dacht: laat me dit maken met Arduino en eenvoudige basiscomponenten.
Hoe dit project werkt
Het is heel eenvoudig. Wanneer u de schakeling op het breadboard hebt gemaakt en de sketch hebt geüpload, opent u de Seriële Monitor en ziet u iets als de onderstaande afbeelding:

Volg de instructies en u bent klaar om te beginnen.
Als u verwarring heeft, bekijk dan simpelweg de demonstratievideo.
Code
Morsecode Broncode
Nu bent u klaar om de Sketch te uploaden. Open uw Arduino IDE en ga naar toolbar File → Open → MorseCode.ino en klik op de upload-knop.
/* Dit programma is voor demonstratie van MORSECODE communicatie die gebruikt werd om informatie geheim te verzenden met codes van combinaties punten . en strepen - Dank aan de open source community Door Jalal Mansoori */
#define SIZE 26
const int ledPin = 8;
const int speakerPin = 12;
const int dotButton = 2;
const int dashButton = 7;
String morseCode = "";
String text = "";
int characterAscii = 0;
int startPos = 0, endPos = 0;
int startPos1 = 0, endPos1 = 0;
String characterCode = "";
int dashButtonState = 0;
int dotButtonState = 0;
// Array van Morsecode voor letters van het Engels Alfabet A tot Z
String letters[SIZE] = {
// A tot I
".-", "-...", "-.-.", "-..", ".", "..-.", "--.", "....", "..",
// J tot R
".---", "-.-", ".-..", "--", "-.", "---", ".--.", "--.-", ".-.",
// S tot Z
"...", "-", "..-", "...-", ".--", "-..-", "-.--", "--.."
};
void setup() {
// setup code hier, om een keer uit te voeren:
// Dingen klaarmaken
pinMode(ledPin, OUTPUT);
pinMode(dotButton, INPUT);
pinMode(dashButton, INPUT);
Serial.begin(9600);
Serial.println("*************************************************************");
Serial.println(" Demonstratie van Morsecode");
Serial.println("*************************************************************");
Serial.println("\nInstructies");
Serial.println("1. Schrijf eerst uw Morsecode");
Serial.println("2. Wanneer u klaar bent, schrijf 1 in het bovenste invoerveld en druk op Enter of klik op de Verzend-knop");
Serial.println("3. Voor spatie tussen letters schrijf 2 en druk op Enter");
Serial.println("4. Voor spatie tussen woorden schrijf 3 en druk op Enter");
Serial.println("5. Dat is alles. De vertaling van de Morsecode wordt dan getoond");
Serial.println("\n\nVoer uw Morsecode hier in");
}
void loop() {
// hoofdcode hier, om herhaaldelijk uit te voeren:
while (Serial.available() > 0) {
int ascii = Serial.read();
switch (ascii) {
case 49: // 49 is ASCII-waarde van 1
Serial.print("\n");
morseCode.concat('#'); // Plaats # aan het einde van morseCode om verdere verwerking te vereenvoudigen
Serial.print("\nUw Morsecode Vertaling: ");
endPos1 = morseCode.indexOf('#');
while (endPos1 < morseCode.length()) {
extractLetters(morseCode.substring(startPos1, endPos1)); // Deze functie zou de letter extraheren zoals de naam suggereert en de code naar tekst converteren EENVOUDIG!
startPos1 = endPos1 + 1;
if (startPos1 == morseCode.length()) {
break;
}
endPos1 = morseCode.indexOf('#', startPos1);
}
startPos1 = 0;
endPos1 = 0;
text = ""; // Voor nieuwe vertaling
morseCode = "";
Serial.println("\n\nVoer uw Morsecode hier in");
break;
case 50: // 50 is ASCII-waarde van 2
morseCode.concat("@");
Serial.print("@");
delay(200);
break;
case 51: // 51 is ASCII-waarde van 3
morseCode.concat("#");
Serial.print("#");
delay(200);
break;
}
}
process();
}
void turnONLedSpeaker() {
// LED AAN
digitalWrite(ledPin, HIGH);
tone(speakerPin, 4699, 300); // tone(speakerPin, frequentie, duur in milliSec)
}
void process() {
dotButtonState = digitalRead(dotButton);
dashButtonState = digitalRead(dashButton);
if (dashButtonState == HIGH) {
turnONLedSpeaker();
morseCode.concat("-"); // Code opslaan in variabele morseCode met concatenatie
Serial.print("-"); // Print gebruikerscode
delay(200);
} else if (dotButtonState == HIGH) {
turnONLedSpeaker();
morseCode.concat(".");
Serial.print(".");
delay(200);
} else {
// LED UIT
digitalWrite(ledPin, LOW);
}
}
char convertIntoText(String characterCode) {
characterAscii = 65; // ASCII voor 'A'
for (int index = 0; index < SIZE; index++) {
if (characterCode == letters[index]) {
return characterAscii;
}
characterAscii++;
}
return '?'; // Onbekend teken
}
void extractLetters(String words) {
words.concat('@'); // Plaats @ aan het einde van woord om verdere verwerking te vereenvoudigen
endPos = words.indexOf('@'); // Lus om individuele Morsecode-teken uit string van woord te extraheren
while (endPos < words.length()) {
characterCode = words.substring(startPos, endPos); // Nu zal CharacterCode in tekst worden geconverteerd
text.concat(convertIntoText(characterCode));
startPos = endPos + 1;
characterCode = ""; // if voorwaarde is om lus te beëindigen wanneer het extraheren van individuele tekencode compleet is
if (startPos == words.length()) {
break;
}
endPos = words.indexOf('@', startPos);
}
Serial.print(text);
Serial.print(" ");
startPos = 0;
endPos = 0;
text = "";
}
Schema's
Instructies voor Digitale Pins van Arduino naar breadboard:
→ pin D2 is verbonden met een been van drukknop1.
→ pin D7 is verbonden met een been van drukknop2.
→ pin D8 is verbonden met +ieve terminal been LED via weerstand
→ En tenslotte pin D12 is verbonden met +ieve terminal been Buzzer via weerstand
En overige verbindingen: bekijk het Schema Afbeelding en U BENT KLAAR!
Productieproces
- LED helderheid regelen met PWM via drukknop op Arduino Mega
- Een DTMF-decoder bouwen met alleen een Arduino – Geen extra IC's nodig
- Bouw een Ultrasonische Zweefapparaat met Arduino – Stap-voor-stap Handleiding
- Morsecode-communicatie met lasermodule – Tweezijdig Arduino-project
- Bouw een Slimme IoT Pot met ESP8266, Arduino & Ultrasonische Sensor – Real-time Monitoring
- Een Arduino Iron Man bouwen: onderdelen, sensoren en stapsgewijze handleiding
- Find Me: Slimme Item Locator met Arduino en Bluetooth
- De massa van de aarde meten met Arduino: een stapsgewijze DIY-gids
- DIY Arduino Luchtbevochtiger Controller met Relais – Veilige Hoogspanningsopstelling
- Realtime afstandsmeting met Arduino Sonar & Processing visualisatie
- Slimme Parkeer Teller: Real-time Voertuigvolging met Arduino, Processing en PHP