Industriële fabricage
Industrieel internet der dingen | Industriële materialen | Onderhoud en reparatie van apparatuur | Industriële programmering |
home  MfgRobots >> Industriële fabricage >  >> Industrial programming >> Verilog

Verilog Tasks begrijpen: Functions vs Tasks, Syntax en Gebruik

Een function is bedoeld om verwerking op de input te doen en een enkele waarde terug te geven, terwijl een task algemener is en meerdere resultaatwaarden kan berekenen en teruggeven via output en inout type argumenten. Tasks kunnen simulatiettijd consumerende elementen bevatten zoals @, posedge en anderen.

Syntax

Een task hoeft geen set argumenten in de poortlijst te hebben, in welk geval deze leeg kan blijven.

// Stijl 1
task [naam];
  input [poortlijst];
  inout [poortlijst];
  output [poortlijst];
  begin
    [statements]
  end
endtask

// Stijl 2
task [naam] (input [poortlijst], inout [poortlijst], output [poortlijst]);
  begin
    [statements]
  end
endtask

// Lege poortlijst
task [naam] ();
  begin
    [statements]
  end
endtask

Statische Task

Als een task statisch is, worden al zijn lidvariabelen gedeeld over verschillende aanroepen van dezelfde task die gelijktijdig gestart zijn.

task sum (input [7:0] a, b, output [7:0] c);
  begin
    c = a + b;
  end
endtask

// of
task sum;
  input [7:0] a, b;
  output [7:0] c;
  begin
    c = a + b;
  end
endtask

initial begin
  reg [7:0] x, y , z;
  sum (x, y, z);
end

De task-aanroepargumenten (x, y, z) corresponderen met de argumenten (a, b, c) gedefinieerd door de task. Omdat a en b inputs zijn, worden waarden van x en y in a en b geplaatst. Omdat c gedeclareerd is als output en verbonden met z tijdens aanroep, wordt de som automatisch doorgegeven aan variabele z vanuit c.

Automatische Task

Het trefwoord automatic maakt de task reentrant, anders is het standaard statisch. Alle items binnen automatische tasks worden dynamisch toegewezen voor elke aanroep en niet gedeeld tussen aanroepen van dezelfde task die gelijktijdig draaien. Let op dat automatic task-items niet benaderd kunnen worden via hiërarchische referenties.

Ter illustratie, overweeg de statische task display die aangeroepen wordt vanuit verschillende initial-blokken die gelijktijdig draaien. In dit geval wordt de integer-variabele binnen de task gedeeld tussen alle aanroepen van de task en moet de getoonde waarde oplopen voor elke aanroep.

module tb;
  initial display();
  initial display();
  initial display();
  initial display();

  // Dit is een statische task
  task display();
    integer i = 0;
    i = i + 1;
    $display("i=%0d", i);
  endtask
endmodule

Simulatie-log

xcelium> run
i=1
i=2
i=3
i=4
xmsim: *W,RNQUIE: Simulation is complete.

Als de task automatisch gemaakt wordt, krijgt elke aanroep van de task een andere ruimte in het simulatiegeheugen en gedraagt zich anders.

module tb;
  initial display();
  initial display();
  initial display();
  initial display();

  // Let op: de task is nu automatic
  task automatic display();
    integer i = 0;
    i = i + 1;
    $display("i=%0d", i);
  endtask
endmodule

Simulatie-log

xcelium> run
i=1
i=1
i=1
i=1
xmsim: *W,RNQUIE: Simulation is complete.

Globale tasks

Tasks die buiten alle modules gedeclareerd zijn, heten globale tasks omdat ze een globale scope hebben en vanuit elke module aangeroepen kunnen worden.

// Deze task is buiten alle modules
task display();
  $display("Hello World !");
endtask

module des;
  initial begin
    display();
  end
endmodule

Simulatie-log

xcelium> run
Hello World !
xmsim: *W,RNQUIE: Simulation is complete.

Als de task binnen de module des gedeclareerd was, zou het aangeroepen moeten worden met referentie naar de module-instantienaam.

module tb;
  des u0();
  initial begin
    u0.display(); // Task is niet zichtbaar in module 'tb'
  end
endmodule

module des;
  initial begin
    display(); // Task definitie is lokaal aan de module
  end
  task display();
    $display("Hello World");
  endtask
endmodule

Simulatie-log

xcelium> run
Hello World
Hello World
xmsim: *W,RNQUIE: Simulation is complete.

Verschil tussen function en task

Hoewel Verilog functies en tasks vergelijkbare doeleinden dienen, zijn er een paar opvallende verschillen.

Function Task
Kan geen tijdsgecontroleerde statements/vertraging hebben, en voert dus uit in dezelfde simulatiettijd-eenheid Kan tijdsgecontroleerde statements/vertraging bevatten en kan pas op een later moment compleet zijn
Kan geen task inschakelen, vanwege bovenstaande regel Kan andere tasks en functies inschakelen
Moet minstens één input-argument hebben en kan geen output of inout argumenten hebben Kan nul of meer argumenten van elk type hebben
Kan slechts één enkele waarde teruggeven Kan geen waarde teruggeven, maar kan hetzelfde effect bereiken met output-argumenten

Wanneer een functie probeert een task aan te roepen of een tijdsconsumerend statement bevat, rapporteert de compiler een fout.

module tb;
  reg signal;
  initial wait_for_1(signal);
  function wait_for_1(reg signal);
    #10;
  endfunction
endmodule

Simulatie-log

#10; | xmvlog: *E,BADFCN (testbench.sv,7|4): illegal time/event control statement within a function or final block or analog initial block [10.3.4(IEEE)].

Task uitschakelen

Tasks kunnen uitgeschakeld worden met het disable-trefwoord.

module tb;
  initial display();
  initial begin
    // Na 50 tijdseenheden, schakel een specifiek benoemd
    // blok T_DISPLAY binnen de task 'display' uit
    #50 disable display.T_DISPLAY;
  end

  task display();
    begin : T_DISPLAY
      $display("[%0t] T_Task gestart", $time);
      #100;
      $display("[%0t] T_Task beëindigd", $time);
    end
    begin : S_DISPLAY
      #10;
      $display("[%0t] S_Task gestart", $time);
      #20;
      $display("[%0t] S_Task beëindigd", $time);
    end
  endtask
endmodule

Wanneer display task gelanceerd werd door het eerste initial-blok, startte T_DISPLAY en werd uitgeschakeld wanneer de tijd 50 eenheden bereikte. Onmiddellijk startte het volgende blok S_DISPLAY en liep tot voltooiing op 80 eenheden.

Simulatie-log

xcelium> run
[0] T_Task gestart
[60] S_Task gestart
[80] S_Task beëindigd
xmsim: *W,RNQUIE: Simulation is complete.

Verilog

  1. Verilog beheersen: Complete tutorial voor digitale schakelingontwerp
  2. Verilog concatenatie beheersen: Een praktische gids
  3. Verilog-toewijzingen begrijpen: types, syntax en best practices
  4. Verilog Blocking vs. Non-Blocking: belangrijkste verschillen uitgelegd
  5. Verilog-functies beheersen voor efficiënt RTL-ontwerp
  6. Verilog Tasks begrijpen: Functions vs Tasks, Syntax en Gebruik
  7. Verilog Hiërarchische Referentie Scope: Naamconflicten in Modules en Blokken vermijden
  8. Verilog Clock Generator: Ontwerp & Implementatie Gids
  9. Verilog Display Tasks beheersen: Efficiënt Debuggen & Loggen
  10. Verilog Math Functions beheersen voor efficiënt Hardware-ontwerp
  11. Verilog $timeformat beheersen: Precisie en Weergave-controle